@echo off
rem = """

if [%1]==[/?] goto :help
echo %* | find "/?" > nul
if errorlevel 1 goto :main

:help
echo usage: %0 [/?]
echo
echo Bootstrap a macOS instance with:
echo
echo * Windows SDK - from MSDN
echo * Chocolatey - package manager
echo * Git - from Chocolatey
echo * Python - from Chocolatey
echo * virtualenv - from pip
echo * SSH key - from ssh-keygen
echo * GitHub public key - with SSH key
echo * conduit - configuration manager
echo
echo optional arguments:
echo         /?              show this help message and exit
goto end

:main

:: Check for admin permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if errorlevel 1 (
  echo Administrator privilages required!
  exit /B 1
)

:: Install Windows SDK
bitsadmin.exe /transfer "Download Windows SDK" https://go.microsoft.com/fwlink/p/?linkid=845298 %~dp0\winsdksetup.exe
if errorlevel 1 exit /B 1
echo Installing: Windows SDK
%~dp0\winsdksetup.exe /features + /q
if errorlevel 1 exit /B 1
del %~dp0\winsdksetup.exe
echo Installed: Windows SDK

:: Install Chocolatey
@"%SystemRoot%\System32\WindowsPowerShell\v1.0\powershell.exe" -NoProfile -InputFormat None -ExecutionPolicy Bypass -Command "iex ((New-Object System.Net.WebClient).DownloadString('https://chocolatey.org/install.ps1'))" && SET "PATH=%PATH%;%ALLUSERSPROFILE%\chocolatey\bin"
if errorlevel 1 exit /B 1
echo Installed: Chocolatey

:: Install Git
choco install cmder --yes
if errorlevel 1 exit /B 1

:: Install Python
choco install python2 --yes
if errorlevel 1 exit /B 1

:: Install virtualenv
"C:\Python27\Scripts\pip.exe" install virtualenv
if errorlevel 1 exit /B 1

:: Generate SSH key
mkdir %USERPROFILE%\.ssh
set /P email="SSH email: "
"C:\tools\cmder\vendor\git-for-windows\usr\bin\ssh-keygen.exe" -t rsa -b 4096 -C "%email%" -N "" -f %USERPROFILE%\.ssh\id_rsa
if errorlevel 1 exit /B 1
goto github

:cleanup
if errorlevel 1 exit /B 1
:: These commands are exectued after the embedded python code below, this is
:: required because commands following the embedded python code result in
:: python syntax errors.
rmdir /Q /S "%~dp0\bootstrap_env
echo "Completed: %0 will now be removed"
start /b "" cmd /c del "%~f0"&exit /b
goto end

:: GitHub public key
:github
"C:\Python27\Scripts\virtualenv.exe" %~dp0\bootstrap_env
if errorlevel 1 exit /B 1
"%~dp0\bootstrap_env\Scripts\pip.exe" install githubpy
if errorlevel 1 exit /B 1
"%~dp0\bootstrap_env\Scripts\python.exe" -x "%~f0"
goto cleanup """

from os import environ
from os.path import join
from getpass import getpass
from sys import stdout
from subprocess import call
from github import GitHub

SEP = '----------------------------------------------------------------------'


def getinput(prompt):
    try:
        return raw_input(prompt)
    except NameError:
        return input(prompt)


def set_github_key():
    username = getinput('GitHub username: ')
    password = getpass('GitHub password: ')
    github = GitHub(username=username, password=password)
    keys = github.user.keys().get()
    id_rsa_pub_path = join(environ['USERPROFILE'], '.ssh', 'id_rsa.pub')
    with open(id_rsa_pub_path, 'r') as id_rsa_pub_file:
        local_key = id_rsa_pub_file.read()
        for key in keys:
            if local_key.startswith(key['key']):
                stdout.write('Satisfied: GitHub public key\n')
                return
        title = getinput('GitHub key name: ')
        github.user.keys().post(title=title, key=local_key)
        stdout.write('Installed: GitHub public key\n')


def show_public_key():
    stdout.write('%s\n' % SEP)
    with open(join(environ['USERPROFILE'], '.ssh', 'id_rsa.pub')) as key:
        stdout.write('%s\n' % key.read())
    stdout.write('%s\n' % SEP)
    getinput('Set other SSH key recipients, press ENTER to continue: ')


def install_conduit():
    path = environ['PATH'].split(';')
    path.append(r'C:\tools\cmder\vendor\git-for-windows\bin')
    environ['PATH'] = ';'.join(path)
    call([r'C:\Python27\Scripts\pip.exe', 'install',
          'git+ssh://git@github.com/kbenzie/conduit.git'])


if __name__ == '__main__':
    try:
        set_github_key()
        show_public_key()
        install_conduit()
    except KeyboardInterrupt:
        exit(1)

rem = """
:end """